linux – gnuplot行类型不希望被更改

你能帮我吗？我希望将一行类型更改为点线.我使用这些命令：

gnuplot> set terminal png size 750,210 nocrop butt font "/usr/share/fonts/truetype/ttf-liberation/LiberationSans-Regular.ttf" 8
gnuplot> set output "/root/data.png"
gnuplot> set xdata time
gnuplot> set timefmt "%Y-%m-%d"
gnuplot> set format x "%b %d"
gnuplot> set ylabel "item1"
gnuplot> set y2label "item2"
gnuplot> set y2tics
gnuplot> set datafile separator "|"
gnuplot> plot "/root/results.txt" using 1:2 title "item1" w lines lt 4,"/root/results.txt" using 1:3 title "item2" with lines

但我总是得到洋红色线.
我使用的是4.6版补丁级别0.
谢谢你的回复.

解决方法

>定义线条样式：

set style line 1 linetype 1 linecolor 7
set style line 2 linetype 1 linecolor rgb "#dd7700"
plot x linestyle 1,x**2 linestyle 2

您必须明确指定使用哪种线条样式.
>如果未指定任何内容,则选择并增加线型而不是线型：

set style line 1 linetype 1 linecolor 7
set style line 2 linetype 1 linecolor rgb "#dd7700"
set style increment user
plot x,x**2

>重新定义默认行类型(在4.6.0版中引入)：

set linetype 1 linecolor 7
set linetype 2 linetype 1 linecolor rgb "magenta"
plot x,x**2

请注意,与线型不同,set linetype的重新定义是持久的;他们不受重置的影响.要重置它们,您必须使用set linetype 1 default.

因此,最小的绘图脚本可能如下所示：

reset
set terminal pngcairo dashed monochrome
set output "/root/data.png"
set xdata time
set timefmt "%Y-%m-%d"
set format x "%b %d"
set datafile separator "|"
set style data lines

plot "/root/results.txt" using 1:2 linetype 1,"" using 1:3 linetype 3

（编辑：四平站长网）

【声明】本站内容均来自网络，其相关言论仅代表作者个人观点，不代表本站立场。若无意侵犯到您的权利，请及时与联系站长删除相关内容!